Die Rechnungszentrale: Tabelle "Rechnungen"

Der Tab Rechnungen ist Dein Finanzamt. Hier wird aus einem erledigten Auftrag eine echte Forderung mit Nummer, Datum und berechnetem Betrag.

Jede Zeile repräsentiert eine Rechnung.

Die Verknüpfungen verstehen

Die Rechnung ist das Endprodukt, das aus dem Kalender-Termin entsteht, über die Tabellen Kunden, Empfänger und Abrechnungsmodelle. Hier ist, wie alles zusammenhängt:

Verknüpfung von Kunden, Empfängern und Abrechnungsmodellen zu Rechnungen

Der Lebenszyklus einer Rechnung

Der Status zeigt Dir, wo sich die Rechnung gerade befindet.

Übersicht der Rechnungs-Tabelle mit den verschiedenen Status-Optionen.

Hier ist der typische Ablauf einer Rechnung:

Lebenszyklus einer Rechnung

Die Status-Optionen im Detail

• Vom System gesetzt:

  • Entwurf: Die Zeile wurde angelegt, aber das Tabellenblatt (Design) fehlt noch.
  • Wird erstellt...: Das Skript arbeitet gerade.
  • Erstellt: Das Tabellenblatt (z.B. "RE-2025-066") existiert. Du kannst es jetzt prüfen.
  • Exportiert: Das PDF liegt im Drive und der E-Mail-Entwurf ist fertig.
  • Fehler: Irgendwas ging schief (meistens fehlt eine Vorlage).

• Von Dir gesetzt (Manuell):

  • Versendet: Du hast auf "Senden" geklickt.
  • Bezahlt: Das Geld ist da. Archivieren!
  • Storniert: Rechnung ist ungültig.
  • Korrektur: Du musst noch etwas ändern.

Funktionen & Aktionen

Du hast zwei Haupt-Werkzeuge im DolmiDesk-Menü, die Du hier (oder im Aufträge-Tab) nutzen kannst.

Die beiden Haupt-Aktionen im Rechnungs-Tab: 'Rechnungen erstellen' und 'Rechnungen löschen (Smart Delete)'.

Rechnungsentwürfe erstellen

Erzeugt für alle ausgewählten Zeilen in der Tabelle Aufträge (Auswahl = Haken gesetzt) einen Rechnungsentwurf.

• Das System erstellt eine neue Zeile in der Tabelle Rechnungen.
• Das System weist die nächste fortlaufende Rechnungsnummer zu und setzt das Rechnungsdatum auf heute.
• Es kopiert die Preise (Stundensatz und gegebenenfalls Fahrtstundensatz sowie das Abrechnungsmodell) fest in die Zeile (Snapshot). Das schützt Dich vor nachträglichen Preisänderungen in den Stammdaten.
• Es erstellt ein neues Tabellenblatt im Design des Empfängers.

warnung

Diese Funktion ist nur für neue Rechnungen gedacht. Wenn Du eine bestehende Rechnung ändern möchtest, bearbeite bitte das Tabellenblatt direkt. Für Mahnungen oder Korrekturen erstelle eine neue Zeile manuell.

Rechnungsentwürfe löschen (Smart Delete)

Wenn Du einen Haken bei einer Rechnung mit dem Status Erstellt oder Entwurf setzt und "Löschen" klickst:

1. Das Tabellenblatt (der Entwurf) wird gelöscht.
2. Die Zeile in der Tabelle Rechnungen wird gelöscht.
3. Der Auftrag im Tab Aufträge wird zurückgesetzt auf "Bereit".

Flexibilität

Du kannst diese Funktionen sowohl im Tab Rechnungen als auch im Tab Aufträge ausführen. Das Ergebnis ist dasselbe.

gefahr

Achte darauf, dass Du nur Rechnungen im Status Entwurf oder Erstellt löschst. Einmal versendete Rechnungen oder als PDF erstellte sollten aus buchhalterischen Gründen nicht gelöscht werden.

Die Berechnungs-Logik

Die Tabelle berechnet vollautomatisch alle Beträge basierend auf dem Auftrag und dem Abrechnungsmodell. Auf der Abbildung 4.1 siehst Du die Logik im Überblick.

Berechnungslogik der Bestandteilen einer Rechnung auf der Grundlage der definierten Abrechnungsmodelle und Pauschalen.

In der Tabelle Rechnungen gibt es mehrere berechnete Spalten, die die verschiedenen Bestandteile der Rechnung darstellen: Honorar, Fahrtkosten, Einsatzdauer, Reisedauer usw. Diese werden automatisch mit Formeln gemäß der Logik (siehe Abbildung 4.1) berechnet.

Hier ist ein Überblick, welche Spalten was berechnen:

Spalte	Berechnung
Honorar	Berechnet das Honorar basierend auf dem Termin-Typ (Vorort, Ausfall, Absage) und dem Abrechnungsmodell.
Fahrtkosten	Berechnet die Fahrtkosten basierend auf dem Abrechnungsmodell, der Distanz und dem Fahrstundensatz. Wenn es keinen Fahrtstundensatz und keine Fahrtpauschale gibt (zum Beispiel wie bei JVEG), werden keine Fahrtkosten separat berechnet - die Reisedauer wird mit der Dolmetschdauer addiert und mit dem entsprechenden Dolmetschstundensatz abgerechnet.
Einsatzdauer	Berechnet die Einsatzdauer, ggf. inklusive Reisezeit, je nach Abrechnungsmodell, falls es keinen Fahrstundensatz und keine Pauschale gibt.
Reisedauer	Berechnet die reine Reisezeit basierend auf dem Auftrag. Dieser Feld bleibt leer, falls es keinen Fahrstundensatz und keine Pauschale gibt.
Distanz aufgerundet	Rundet die Reisedistanz auf volle Kilometer auf, um Pauschalen korrekt anzuwenden.

gefahr

Die meisten Spalten enthalten komplexe ARRAYFORMULA-Formeln in der Überschrift oder der ersten Zeile. Wenn Du Werte manuell überschreibst, zerstörst Du die Automatik für alle nachfolgenden Zeilen!

Hier ist die Erklärung der wichtigsten Berechnungen.

Honorar & Einsatz

Die Spalte Honorar ist intelligent. Sie prüft:

1. War es ein normaler Termin? → Berechne Einsatzdauer * Stundensatz.
2. War es ein Ausfall? → Suche den Pauschalpreis in der Tabelle "Ausfallpauschalen" basierend auf der geplanten Dauer.

Wiederherstellungs-Code für Honorar:

=ArrayFormula(LET(
  a_id; Rechnungen[A-ID];
  am; Rechnungen[Abrechnungsmodell];
  stundensatz; N(Rechnungen[Stundensatz]);
  einsatzdauer; Rechnungen[Einsatzdauer];
  typ; XLOOKUP(a_id; Aufträge[A-ID]; Aufträge[Typ]);
  einsatz_auf; CEILING((einsatzdauer-0,00000001)*2)/2;
  pauschale_map; MAP(am; einsatz_auf; LAMBDA(x_am; d;
    LET(
      bis_text; FILTER(Ausfallpauschalen[Bis]; Ausfallpauschalen[Abrechnungsmodell]=x_am);
      paus; FILTER(Ausfallpauschalen[Pauschale]; Ausfallpauschalen[Abrechnungsmodell]=x_am);
      bis_stunden; IFERROR(TIMEVALUE(bis_text)*24; VALUE(LEFT(bis_text; FIND(":"; bis_text)-1)));
      pos; IFERROR(MATCH(TRUE; d<=bis_stunden; 0); ROWS(bis_stunden));
      INDEX(paus; pos)
    )
  ));
  honorar;
    IF(
      a_id="";
      ;
      IF(
        (typ="Vorort") + (typ="Online");
        einsatzdauer*stundensatz;
        IF(
          (typ="Ausfall") + (typ="Absage");
          IFERROR(pauschale_map; einsatzdauer*stundensatz);
          ""
        )
      )
    );
  honorar
))

Fahrtkosten

Bevor die Fahrkosten berechnet werden, muss erst mal die Reisedistanz berechnet werden, auf deren Basis die Fahrtkosten ermittelt werden. Diese werden beim Import in der Tabelle "Aufträge" berechnet, aber für die Pauschalen-Logik ist es sinvoll die Distanz aufzurunden, weil Pauschalen meistens in festen vollen Kilometer-Bereichen definiert sind.

Damit Du bei gefahrenen 29,99 km nicht leer ausgehst, wird die Distanz in der Spalte Distanz aufgerundet auf nach mathematischen Prinzip aufgerundet. Diese Spalte wird nur für die Berechnung der Fahrtkosten in Fahrtkosten verwendet.

Die Spalte Fahrtkosten prüft:

1. Gibt es eine Fahrtpauschale für diesen Kunden? (Tabelle "Fahrtpauschalen").
2. Falls ja: Liegt die Entfernung innerhalb der Grenzen? → Nimm den Pauschalpreis.
3. Falls nein: gibt es einen Fahrstundensatz?
4. Falls ja: Berechne Reisedauer * Fahrstundensatz.
5. Bei Absage oder Online: Immer 0,00 €.

Hier ist ein Video-Tutorial, das die Logik erklärt, wenn Du nach JVEG mit und ohne definierten Fahrstundensatz arbeitest:

Demo: So berechnet DolmiDesk™ Fahrtkosten für JVEG

Sieh Dir an, wie DolmiDesk™ die Fahrtkosten basierend auf Abrechnungsmodellen, Pauschalen und Fahrstundensätzen berechnet.

Wiedergabeposition

Lautstärke

0:00 von 0:00

Wiederherstellungs-Code für Distanz aufgerundet:

=ArrayFormula(LET(
  a_id; Rechnungen[A-ID];
  abrechnungsmodell; Rechnungen[Abrechnungsmodell];

  reisedistanz; XLOOKUP(a_id; Aufträge[A-ID]; Aufträge[Reisedistanz]);
  anreisedistanz; XLOOKUP(a_id; Aufträge[A-ID]; Aufträge[Anreisedistanz]);
  abreisedistanz; XLOOKUP(a_id; Aufträge[A-ID]; Aufträge[Abreisedistanz]);

  distanz_berechnet; MAP(abrechnungsmodell; reisedistanz; anreisedistanz; abreisedistanz; LAMBDA(am; rd; ad; abd;
    LET(
      typ_pausch; IFERROR(INDEX(FILTER(Fahrtpauschalen[Typ]; Fahrtpauschalen[Abrechnungsmodell]=am); 1); "Gesamt");
      raw_dist; IF(typ_pausch="Einfach"; MAX(ad; abd); rd);
      ROUNDUP(raw_dist)
    )
  ));

  IF(a_id="";; distanz_berechnet)
))

Wiederherstellungs-Code für Fahrtkosten:

=ArrayFormula(LET(
  a_id; Rechnungen[A-ID];
  abrechnungsmodell; Rechnungen[Abrechnungsmodell];
  fahrstundensatz; N(Rechnungen[Fahrstundensatz]);
  reisedauer; Rechnungen[Reisedauer];
  typ; XLOOKUP(a_id; Aufträge[A-ID]; Aufträge[Typ]);
  reisedistanz; XLOOKUP(a_id; Aufträge[A-ID]; Aufträge[Reisedistanz]);
  anreisedistanz; XLOOKUP(a_id; Aufträge[A-ID]; Aufträge[Anreisedistanz]);
  pauschale_map; MAP(abrechnungsmodell; reisedistanz; anreisedistanz; LAMBDA(am; rd; ad;
    LET(
      bis_text; FILTER(Fahrtpauschalen[Bis]; Fahrtpauschalen[Abrechnungsmodell]=am);
      paus; FILTER(Fahrtpauschalen[Pauschale]; Fahrtpauschalen[Abrechnungsmodell]=am);
      typ_pausch; FILTER(Fahrtpauschalen[Typ]; Fahrtpauschalen[Abrechnungsmodell]=am);
      bis_km; N(VALUE(SUBSTITUTE(bis_text;" km";"")));
      pos; IFERROR(MATCH(TRUE; IF(typ_pausch="Einfach"; ad<=bis_km; rd<=bis_km); 0); ROWS(bis_km));
      INDEX(paus; pos)
    )
  ));
  hat_pauschale; NOT(ISNA(XMATCH(abrechnungsmodell; Fahrtpauschalen[Abrechnungsmodell])));
  fahrtkosten; IFS(
    typ="Absage"; 0;
    OR(typ="Vorort"; typ="Online"; typ="Ausfall");
      IF(hat_pauschale; pauschale_map;
        IF(ISBLANK(fahrstundensatz); 0; reisedauer*fahrstundensatz)
      );
    TRUE;
  );
  IF(a_id=""; ; fahrtkosten)
))

Zeiten & Dauer

Die Zeiten werden immer auf die nächste halbe Stunde gerundet. Zum Beispiel: 1:10 wird zu 1,5, 2:40 wird zu 3.

hinweis

Im Prozess der Umwandlung der Zeit in Dezimalstunden (z.B. 1:30 → 1,5) werden die Werte auf 6 Nachkommastellen gerundet, um Rundungsfehler zu vermeiden.

Die Zeiten werden basierend auf dem Abrechnungsmodell unabhängig oder zusammengerechnet gerundet.

Wenn kein Fahrstundensatz definiert ist, wird die Reisezeit auf die Einsatzzeit aufgeschlagen (JVEG-Logik), falls keine Pauschale definiert ist.

Wiederherstellungs-Code für Einsatzdauer:

=ArrayFormula(LET(
  a_id; Rechnungen[A-ID];
  am; Rechnungen[Abrechnungsmodell];
  fss; Rechnungen[Fahrstundensatz];

  d_dauer; XLOOKUP(a_id; Aufträge[A-ID]; Aufträge[Dolmetschdauer]);
  r_dauer; XLOOKUP(a_id; Aufträge[A-ID]; Aufträge[Reisedauer]);

  hat_pausch; NOT(ISNA(XMATCH(am; Fahrtpauschalen[Abrechnungsmodell])));

  d_h; ROUND(N(d_dauer)*24; 6);
  r_h; ROUND(N(r_dauer)*24; 6);

  gesamt; IF(ISBLANK(fss); IF(hat_pausch; d_h; d_h + r_h); d_h);

  res; CEILING((gesamt - 0,00000001)*2)/2;

  IF(a_id=""; ; res)
))

tipp

Wenn Du eine komplett andere Berechnungslogik benötigst, kannst Du die Formeln in den Überschriften der jeweiligen Spalten anpassen. Achte darauf, dass Du die ARRAYFORMULA-Struktur beibehältst, damit die Automatik für alle Zeilen erhalten bleibt. Der Skript zum Erstellen der Rechnungsentwürfen braucht nur die Spalten A-ID, Rechnungsnummer und Rechnungsdatum. Alle anderen Spalten können frei angepasst werden.

Berechnungsbeispiele

Hier sind einige Beispiele, wie die Berechnungen in der Tabelle Rechnungen funktionieren, basierend auf verschiedenen Szenarien.

Vorort-Termin mit Fahrtpauschale (Gesamtstrecke) – Abrechnungsmodell LWV

Im Folgenden wird ein Vorort-Dolmetschtermin beschrieben. Die Tabelle gibt alle relevanten Ausgangsdaten an, die anschließend in der Tabelle Rechnungen weiterverarbeitet werden.

Feld	Wert
Termin-Typ	Vorort
Dolmetschdauer	2:15 Stunden
Reisedauer	1:43 Stunden
Reisedistanz	47 km
Abrechnungsmodell	LWV
Stundensatz	93,00 €

Daraus ergibt sich in der Tabelle Rechnungen folgende Berechnung:

Feld	Wert
Abrechenbare Dauer	2,5 Stunden
Honorar	$2{,}5 \times 93{,}00\,€ = 232{,}50\,€$
Fahrtstundensatz	—
Reisedauer	—
Distanz aufgerundet	50 km
Fahrtkosten	Pauschale 0–50 km: 66,00 €
Vorbereitungspauschale	—
Sonstiges	—
Gesamtbeitrag	$(232{,}50 + 66{,}00 = 298{,}50\,€)$

Erläuterungen zu den Berechnungsschritten

Abrechenbare Dauer

Die Dolmetschdauer beträgt 2 Stunden und 15 Minuten. Dies entspricht in Dezimalstunden:

$$2{\,\text{h}} + \frac{15}{60}\,\text{h} = 2{,}25\,\text{h}$$

Da jede Dauer auf 0,5 Stunden gerundet wird, ergibt sich:

$$2{,}25\,\text{h} \longrightarrow 2{,}5\,\text{h}$$

info

Die Reisedauer wird in diesem Fall nicht zur abgerechneten Dauer hinzugerechnet, da das Abrechnungsmodell LWV eine Fahrtpauschale vorsieht.

Honorarberechnung

Das Honorar ergibt sich aus:

$$\text{Honorar} = \text{abgerechnete Stunden} \times \text{Stundensatz}$$

Also:

$$2{,}5 \times 93{,}00\,€ = 232{,}50\,€$$

Distanz aufgerundet

Die gefahrene Distanz (gesamte Strecke) beträgt 47 km. Da die Pauschalen in vollen Kilometern definiert sind, wird die Distanz auf volle Kilometer aufgerundet:

$$47\,\text{km} \longrightarrow 50\,\text{km}$$

Fahrtkosten

Die aufgerundete Distanz beträgt 50 km. Für das LWV-Modell gilt die Pauschalregel:

• für $0{-}50\,\text{km}$: 66,00 €
• für $51{-}100\,\text{km}$: 110,00 €
• für $101{-}170\,\text{km}$: 164,00 €
• ab $171\,\text{km}$: 219,00 €

Da 50 km in das 1. Intervall fallen, wird die Pauschale von 66,00 € berechnet.

Gesamtbetrag

Der Gesamtbetrag ergibt sich aus Honorar + Fahrtkosten:

$$232{,}50\,€ + 66{,}00\,€ = 298{,}50\,€$$

Vorort-Termin mit Fahrtpauschale (einfache Strecke) - Abrechnungsmodell HessBGGAV

Im Folgenden wird ein Vorort-Dolmetschtermin mit einer einfachen Fahrtpauschale beschrieben. Die Tabelle gibt alle relevanten Ausgangsdaten an, die anschließend in der Tabelle Rechnungen weiterverarbeitet werden.

Feld	Wert
Termin-Typ	Vorort
Dolmetschdauer	0:58 Stunden
Reisedauer	1:21 Stunden
Reisedistanz (hin)	21 km
Reisedistanz (zurück)	26 km
Abrechnungsmodell	HessBGGAV
Stundensatz	93,00 €

Daraus ergibt sich in der Tabelle Rechnungen folgende Berechnung:

Feld	Wert
Abrechenbare Dauer	1 Stunde
Honorar	$1 \times 93{,}00\,€ = 93{,}00\,€$
Fahrtstundensatz	—
Reisedauer	—
Distanz aufgerundet	30 km
Fahrtkosten	Pauschale 0–50 km: 46,00 €
Vorbereitungspauschale	—
Sonstiges	—
Gesamtbeitrag	$(93{,}00 + 46{,}00 = 139{,}00\,€)$

Erläuterungen zu den Berechnungsschritten

Abrechenbare Dauer

Die Dolmetschdauer beträgt 1 Stunde. Dies entspricht in Dezimalstunden:

$$1{\,\text{h}} + \frac{0}{60}\,\text{h} = 1{,}00\,\text{h}$$

Da jede Dauer auf 0,5 Stunden gerundet wird, ergibt sich:

$$1{,}00\,\text{h} \longrightarrow 1{,}0\,\text{h}$$

info

Die Reisedauer wird in diesem Fall nicht zur abgerechneten Dauer hinzugerechnet, da das Abrechnungsmodell LWV eine Fahrtpauschale vorsieht.

Honorarberechnung

Das Honorar ergibt sich aus:

$$\text{Honorar} = \text{abgerechnete Stunden} \times \text{Stundensatz}$$

Also:

$$1{,}0 \times 93{,}00\,€ = 93{,}00\,€$$

Distanz aufgerundet

HessBGGAV verwendet die einfache Fahrtstrecke für die Pauschalenberechnung. Das bedeutet, es wird die größere der beiden Strecken (hin oder zurück) genommen.

Die hin- und zurück gefahrenen Distanzen sind 21 km und 26 km. Die größere Distanz ist 26 km. Diese wird aufgerundet:

$$26\,\text{km} \longrightarrow 30\,\text{km}$$

Fahrtkosten

Die aufgerundete Distanz beträgt 30 km. Für das LWV-Modell gilt die Pauschalregel:

• für $0{-}50\,\text{km}$: 46,00 €
• für $51{-}70\,\text{km}$: 59,00 €
• für $71{-}90\,\text{km}$: 72,00 €
• für $91{-}100\,\text{km}$: 85,00 €
• für $101{-}150\,\text{km}$: 98,00 €
• ab $171\,\text{km}$: 150,00 €

Da 30 km in das 1. Intervall fallen, wird die Pauschale von 46,00 € berechnet.

Gesamtbetrag

Der Gesamtbetrag ergibt sich aus Honorar + Fahrtkosten:

$$93{,}00\,€ + 46{,}00\,€ = 139{,}00\,€$$

Vorort-Termin mit Fahrtzeit gemeinsam mit Dolmetschzeit - Abrechnungsmodell JVEG

Im Folgenden wird ein Vorort-Dolmetschtermin nach JVEG berechnet, indem die Reisedauer und die Dolmetschdauer zu der gesamten Einsatzdauer addiert werden. Die Tabelle gibt alle relevanten Ausgangsdaten an, die anschließend in der Tabelle Rechnungen weiterverarbeitet werden.

Feld	Wert
Termin-Typ	Vorort
Dolmetschdauer	3:21 Stunden
Reisedauer	0:49 Stunden
Reisedistanz	58 km
Abrechnungsmodell	JVEG
Stundensatz	93,00 €

Daraus ergibt sich in der Tabelle Rechnungen folgende Berechnung:

Feld	Wert
Abrechenbare Dauer	3,5 Stunden + 1 Stunde = 4,5 Stunden
Honorar	$4,5 \times 93{,}00\,€ = 418{,}50\,€$
Fahrtstundensatz	—
Reisedauer	—
Distanz aufgerundet	—
Fahrtkosten	—
Vorbereitungspauschale	—
Sonstiges	—
Gesamtbeitrag	$418{,}50\,€$

Erläuterungen zu den Berechnungsschritten

Abrechenbare Dauer

Die Dolmetschdauer beträgt 3:21 Stunden. Dies entspricht in Dezimalstunden:

$$3{\,\text{h}} + \frac{21}{60}\,\text{h} = 3{,}35\,\text{h}$$

Da jede Dauer auf 0,5 Stunden gerundet wird, ergibt sich:

$$3{,}35\,\text{h} \longrightarrow 3{,}5\,\text{h}$$

Die Reisedauer wird in diesem Fall zu der Dolmetschdauer hinzugerechnet, da das Abrechnungsmodell JVEG keinen Fahrstundensatz oder Pauschale vorsieht.

Die Reisedauer beträgt 0:49 Stunden. Dies entspricht in Dezimalstunden:

$$0{\,\text{h}} + \frac{49}{60}\,\text{h} = 0{,}8167\,\text{h}$$

Da jede Dauer auf 0,5 Stunden gerundet wird, ergibt sich:

$$0{,}8167\,\text{h} \longrightarrow 1{,}0\,\text{h}$$

Die gesamte abgerechnete Dauer ist somit:

$$3{,}5\,\text{h} + 1{,}0\,\text{h} = 4{,}5\,\text{h}$$

Honorarberechnung

Das Honorar ergibt sich aus:

$$\text{Honorar} = \text{abgerechnete Stunden} \times \text{Stundensatz}$$

Also:

$$1{,}0 \times 93{,}00\,€ = 93{,}00\,€$$

Distanz aufgerundet

Die distanz wird in diesem Fall nicht für die Berechnung der Fahrtkosten verwendet, da das Abrechnungsmodell JVEG keinen Fahrstundensatz oder Pauschale vorsieht.

Fahrtkosten

Die Fahrtkosten werden in diesem Fall nicht berechnet, da das Abrechnungsmodell JVEG keinen Fahrstundensatz oder Pauschale vorsieht.

Gesamtbetrag

Der Gesamtbetrag ergibt sich alleine aus dem Honorar:

$$418{,}50\,€$$

Vorort-Termin mit Fahrtzeit separat abgerechnet

Im Folgenden wird derselbe Vorort-Dolmetschtermin berechnet, diesmal jedoch mit separat abgerechneter Fahrtzeit. Die Dolmetschzeit wird mit dem normalen Stundensatz, die Fahrtzeit mit einem eigenen Fahrtstundensatz abgerechnet.

Feld	Wert
Termin-Typ	Vorort
Dolmetschdauer	3:21 Stunden
Reisedauer	0:49 Stunden
Reisedistanz	58 km
Abrechnungsmodell	Fahrtstundensatz
Stundensatz	93,00 €
Fahrtstundensatz	60,00 €

Daraus ergibt sich in der Tabelle Rechnungen folgende Berechnung:

Feld	Wert
Abrechenbare Dauer	3,5 Stunden (nur Dolmetschen)
Honorar	$3{,}5 \times 93{,}00\,€ = 325{,}50\,€$
Fahrtstundensatz	60,00 €
Reisedauer	1,0 Stunden
Distanz aufgerundet	— (nicht relevant für die Berechnung)
Fahrtkosten	$1{,}0 \times 60{,}00\,€ = 60{,}00\,€$
Vorbereitungspauschale	—
Sonstiges	—
Gesamtbeitrag	$325{,}50\,€ + 60{,}00\,€ = 385{,}50\,€$

Erläuterungen zu den Berechnungsschritten

Abrechenbare Dauer (Dolmetschzeit)

Die Dolmetschdauer beträgt 3:21 Stunden. Dies entspricht in Dezimalstunden:

$$3{\,\text{h}} + \frac{21}{60}\,\text{h} = 3{,}35\,\text{h}$$

Da jede Dauer auf 0,5 Stunden gerundet wird, ergibt sich:

$$3{,}35\,\text{h} \longrightarrow 3{,}5\,\text{h}$$

Da in diesem Abrechnungsmodell die Fahrtzeit separat über einen Fahrtstundensatz abgerechnet wird, geht in die abgerechnete Dauer für das Honorar nur die Dolmetschzeit ein:

$$\text{abgerechnete Dolmetschzeit} = 3{,}5\,\text{h}$$

Honorarberechnung (Dolmetschen)

Das Honorar ergibt sich aus:

$$\text{Honorar} = \text{abgerechnete Dolmetschstunden} \times \text{Stundensatz}$$

Also:

$$3{,}5 \times 93{,}00\,€ = 325{,}50\,€$$

Reisedauer und Fahrtzeit-Abrechnung

Die Reisedauer beträgt 0:49 Stunden. Dies entspricht in Dezimalstunden:

$$0{\,\text{h}} + \frac{49}{60}\,\text{h} = 0{,}8167\,\text{h}$$

Auch hier wird auf 0,5 Stunden gerundet:

$$0{,}8167\,\text{h} \longrightarrow 1{,}0\,\text{h}$$

Diese 1,0 Stunde wird nicht zur Dolmetschzeit hinzuaddiert, sondern vollständig über den Fahrtstundensatz abgerechnet.

Distanz aufgerundet

Die Distanz von 58 km wird in diesem Beispiel nicht zur Berechnung herangezogen, da die Fahrtkosten ausschließlich über die Fahrtzeit (Fahrstundensatz × Reisedauer) abgerechnet werden.

Daher:

• Distanz aufgerundet: nicht relevant → —

Fahrtkosten

Die Fahrtkosten berechnen sich aus:

$$\text{Fahrtkosten} = \text{abgerechnete Reisedauer} \times \text{Fahrtstundensatz}$$

Also:

$$1{,}0 \times 60{,}00\,€ = 60{,}00\,€$$

Gesamtbetrag

Der Gesamtbetrag setzt sich zusammen aus:

• Honorar (Dolmetschen): 325,50 €
• Fahrtkosten (Fahrtzeit): 60,00 €

Damit ergibt sich:

$$325{,}50\,€ + 60{,}00\,€ = 385{,}50\,€$$

Weitere Felder

• Rechnungsart: Standard ist "Rechnung". Du kannst dies manuell auf "Korrektur" oder "Mahnung" ändern.
• Leistungsdatum: Wird automatisch aus dem Auftrag geholt.
• Stundensatz & Fahrstundensatz: Diese Werte werden beim Erstellen der Rechnung fest hineingeschrieben ("Snapshot"). Du kannst sie hier für diese eine Rechnung ändern, ohne die Stammdaten anzufassen.